AC_INIT([Haskell readline package], [1.0], [libraries@haskell.org], [readline])


FP_ARG_READLINE

if test "$enable_readline" = no; then
  READLINE_BUILD_PACKAGE=no
  BUILD_PACKAGE_BOOL=False
else

# Safety check: Ensure that we are in the correct source directory.
AC_CONFIG_SRCDIR([include/HsReadline.h])
 
AC_CONFIG_HEADERS([include/HsReadlineConfig.h])

READLINE_INCLUDE_DIRS=
READLINE_LIB_DIRS=
if test "x$readline_libraries" != "xNONE"; then
  LDFLAGS="-L$readline_libraries $LDFLAGS"
  READLINE_LIB_DIRS=$readline_libraries
fi
if test "x$readline_includes" != "xNONE"; then
  CPPFLAGS="-I$readline_includes $CPPFLAGS"
  READLINE_INCLUDE_DIRS=$readline_includes
fi
AC_SUBST(READLINE_INCLUDE_DIRS)
AC_SUBST(READLINE_LIB_DIRS)

AC_PROG_CC

dnl ** check for readline, for Hugs and hslibs' Readline
dnl ncurses supersedes termcap and curses, but for compatibility,
dnl we have to check for all...
AC_CHECK_LIB(ncurses, tputs, HaveLibTermcap=YES; LibTermcap=ncurses,
  AC_CHECK_LIB(termcap, tputs, HaveLibTermcap=YES; LibTermcap=termcap,
    AC_CHECK_LIB(curses, tputs, HaveLibTermcap=YES; LibTermcap=curses,
      HaveLibTermcap=NO; LibTermcap=not-installed)))

if test $HaveLibTermcap = YES ; then
  LIBS="-l$LibTermcap $LIBS"
  AC_CHECK_LIB(readline, readline, HaveLibReadline=YES, HaveLibReadline=NO)
fi

dnl ** is our readline really readline, or is it BSD's libedit?
if test x"$HaveLibReadline" = xYES ; then
  AC_CHECK_LIB(readline, rl_readline_version, ReadlineIsLibedit=NO, ReadlineIsLibedit=YES)
fi

if test $HaveLibTermcap = YES && test x"$HaveLibReadline" = xYES && test x"$ReadlineIsLibedit" = xNO ; then
  HAVE_READLINE=YES
  READLINE_LIBS="readline $LibTermcap"
else
  HAVE_READLINE=NO
  READLINE_LIBS=
fi
AC_SUBST(READLINE_LIBS)

if test x"$HaveLibReadline" = xYES && test x"$ReadlineIsLibedit" = xNO ; then
  AC_CHECK_LIB(readline, rl_erase_empty_line,
    [AC_DEFINE([HAVE_READLINE_4], [1], [Define to 1 if readline has version >= 4.0.])],
    [AC_DEFINE([HAVE_READLINE_4], [0], [Define to 1 if readline has version >= 4.0.])])
  AC_CHECK_LIB(readline, rl_free_undo_list,
    [AC_DEFINE([HAVE_READLINE_4_2], [1], [Define to 1 if readline has version >= 4.2.])],
    [AC_DEFINE([HAVE_READLINE_4_2], [0], [Define to 1 if readline has version >= 4.2.])])
else
  AC_DEFINE([HAVE_READLINE_4], [0], [Define to 1 if readline has version >= 4.0.])
  AC_DEFINE([HAVE_READLINE_4_2], [0], [Define to 1 if readline has version >= 4.2.])
fi

if test "$HAVE_READLINE" = YES; then
  READLINE_BUILD_PACKAGE=yes
  BUILD_PACKAGE_BOOL=True
else
  READLINE_BUILD_PACKAGE=no
  BUILD_PACKAGE_BOOL=False
fi

fi

AC_SUBST([READLINE_BUILD_PACKAGE])
AC_SUBST([BUILD_PACKAGE_BOOL])
AC_SUBST([READLINE_CFLAGS])
AC_SUBST([READLINE_LIBS])

AC_CONFIG_FILES([config.mk readline.buildinfo])
AC_OUTPUT